# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//chrome/common/features.gni")
import("//third_party/protobuf/proto_library.gni")

proto_library("proto") {
  sources = [
    "client_model.proto",
    "crx_info.proto",
    "download_file_types.proto",
  ]
}

source_set("safe_browsing") {
  sources = [
    "file_type_policies.cc",
    "file_type_policies.h",
  ]

  if (safe_browsing_mode == 1) {
    sources += [
      "archive_analyzer_results.cc",
      "archive_analyzer_results.h",
      "binary_feature_extractor.cc",
      "binary_feature_extractor.h",
      "binary_feature_extractor_mac.cc",
      "binary_feature_extractor_win.cc",
      "download_protection_util.cc",
      "download_protection_util.h",
      "ipc_protobuf_message_macros.h",
      "ipc_protobuf_message_null_macros.h",
      "mach_o_image_reader_mac.cc",
      "mach_o_image_reader_mac.h",
      "pe_image_reader_win.cc",
      "pe_image_reader_win.h",
      "protobuf_message_log_macros.h",
      "protobuf_message_read_macros.h",
      "protobuf_message_write_macros.h",
      "zip_analyzer.cc",
      "zip_analyzer.h",
    ]
    if (is_posix) {
      sources += [ "binary_feature_extractor_posix.cc" ]
    }
  }

  public_deps = [
    "//base:i18n",
    "//chrome/browser:resources",
    "//chrome/common:mojo_bindings",
    "//chrome/common/safe_browsing:proto",
    "//components/safe_browsing:csd_proto",
    "//crypto",
    "//ipc",
    "//third_party/zlib/google:zip",
    "//ui/base",
  ]
}