# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ios/ios_sdk.gni")
import("//build/config/ios/rules.gni")
import("//ios/build/chrome_build.gni")

config("config") {
  include_dirs = [ "src/Sources" ]
  visibility = [ ":material_internationalization_ios" ]
}

ios_framework_bundle("material_internationalization_ios") {
  output_name = "MDFInternationalization"
  sources = [
    "src/Sources/MDFInternationalization.h",
    "src/Sources/MDFRTL.h",
    "src/Sources/MDFRTL.m",
    "src/Sources/UIImage+MaterialRTL.h",
    "src/Sources/UIImage+MaterialRTL.m",
    "src/Sources/UIView+MaterialRTL.h",
    "src/Sources/UIView+MaterialRTL.m",
  ]
  public_headers = [
    "src/Sources/MDFRTL.h",
    "src/Sources/UIImage+MaterialRTL.h",
    "src/Sources/UIView+MaterialRTL.h",
  ]

  libs = [
    "CoreImage.framework",
    "UIKit.framework",
  ]
  public_configs = [ ":config" ]
  configs -= [
    "//build/config/gcc:symbol_visibility_hidden",
    "//build/config/compiler:chromium_code",
  ]
  configs += [
    "//build/config/compiler:enable_arc",
    "//build/config/compiler:no_chromium_code",
    "//build/config/gcc:symbol_visibility_default",
  ]

  _project_version = "1.0"
  _bundle_identifier =
      "$ios_app_bundle_id_prefix.$chromium_bundle_id.$output_name"

  info_plist = "src/Sources/Info.plist"
  extra_substitutions = [
    "PRODUCT_BUNDLE_IDENTIFIER=$_bundle_identifier",
    "CURRENT_PROJECT_VERSION=$_project_version",
  ]
}