# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/jumbo.gni")

# Intentionally depends on generator targets so to depend only on generated
# mojo biding header files. This is needed to use mojo interfaces from a static
# library such as platform:test_support without causing duplicated symbols.
# There is no tool to detect missing indirect generated header dependency today
# and this is easy to be broken when mojom files are updated to depend on
# another.
jumbo_source_set("generator") {
  public_deps = [
    "//third_party/WebKit/common:mojo_platform_bindings_blink__generator",
    "//url/mojo:url_mojom_gurl_blink__generator",
    "//url/mojo:url_mojom_gurl_shared__generator",
  ]
}

jumbo_source_set("blob") {
  visibility = [ "//third_party/WebKit/Source/*" ]

  sources = [
    "BlobBytesProvider.cpp",
    "BlobBytesProvider.h",
    "BlobData.cpp",
    "BlobData.h",
    "BlobRegistry.cpp",
    "BlobRegistry.h",
    "BlobURL.cpp",
    "BlobURL.h",
  ]

  configs += [
    "//third_party/WebKit/Source:non_test_config",
    "//third_party/WebKit/Source/platform:blink_platform_config",
    "//third_party/WebKit/Source/platform:blink_platform_implementation",
  ]

  public_deps = [
    "//third_party/WebKit/common:mojo_platform_bindings_blink",
    "//third_party/WebKit/public:blink_headers",
  ]
}

jumbo_source_set("unit_tests") {
  visibility = [ "//third_party/WebKit/Source/platform:*" ]
  testonly = true

  sources = [
    "BlobBytesProviderTest.cpp",
    "BlobDataTest.cpp",
  ]

  configs += [ "//third_party/WebKit/Source/platform:blink_platform_config" ]

  deps = [
    "//base/test:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//third_party/WebKit/Source/platform:platform",
  ]
}