# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ios/web/js_compile.gni")

source_set("browser") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "ios_translate_driver.h",
    "ios_translate_driver.mm",
    "js_language_detection_manager.h",
    "js_language_detection_manager.mm",
    "js_translate_manager.h",
    "js_translate_manager.mm",
    "language_detection_controller.h",
    "language_detection_controller.mm",
    "string_clipping_util.cc",
    "string_clipping_util.h",
    "translate_controller.h",
    "translate_controller.mm",
  ]

  deps = [
    ":injected_js",
    "//base",
    "//components/language/core/browser",
    "//components/prefs",
    "//components/translate/core/browser",
    "//components/translate/core/common",
    "//components/translate/core/language_detection",
    "//ios/web",
    "//ui/base",
    "//url",
  ]
}

js_compile_checked("injected_js") {
  visibility = [ ":browser" ]
  sources = [
    "resources/language_detection.js",
    "resources/translate_ios.js",
  ]
}

source_set("unit_tests") {
  configs += [ "//build/config/compiler:enable_arc" ]
  testonly = true
  sources = [
    "js_translate_manager_unittest.mm",
    "language_detection_controller_unittest.mm",
    "string_clipping_util_unittest.cc",
    "translate_controller_unittest.mm",
  ]

  deps = [
    ":browser",
    "//base",
    "//components/prefs:test_support",
    "//components/resources",
    "//components/translate/core/browser",
    "//ios/web/public/test",
    "//ios/web/public/test/fakes",
    "//net:net",
    "//testing/gtest",
    "//third_party/ocmock",
    "//ui/base",
    "//url",
  ]
}