# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build_overrides/build.gni")
import("//build/config/ui.gni")  # import the use_x11 variable

if (build_with_chromium) {
  angle_root = "//third_party/angle"

  import("//ui/ozone/ozone.gni")
} else {
  angle_root = "//"

  declare_args() {
    ozone_platform_gbm = false
  }
}

angle_enable_d3d9 = false
angle_enable_d3d11 = false
angle_enable_gl = false
angle_enable_gl_null = false
angle_enable_vulkan = false
angle_enable_null = true

if (is_win) {
  angle_enable_d3d9 = true
  angle_enable_d3d11 = true
  angle_enable_gl = true
  angle_enable_gl_null = true
  angle_enable_vulkan = true

  import("//build/config/win/visual_studio_version.gni")
} else if (is_linux && use_x11 && !is_chromeos) {
  angle_enable_gl = true
  angle_enable_gl_null = true
  angle_enable_vulkan = true
} else if (is_mac || ozone_platform_gbm) {
  angle_enable_gl = true
  angle_enable_gl_null = true
} else if (is_android) {
  angle_enable_gl = true
  angle_enable_gl_null = true
}

angle_enable_essl = true
angle_enable_glsl = true
angle_enable_hlsl = false

if (angle_enable_d3d9 || angle_enable_d3d11) {
  angle_enable_hlsl = true
}