# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ios/rules.gni")

ios_app_bundle("ios_web_view_shell") {
  info_plist = "Info.plist"

  deps = [
    ":shell",
  ]
  bundle_deps = [ "//ios/web_view:web_view+bundle" ]

  configs += [ "//build/config/compiler:enable_arc" ]
}

source_set("shell") {
  sources = [
    "shell_app_delegate.h",
    "shell_app_delegate.m",
    "shell_exe_main.m",
    "shell_translation_delegate.h",
    "shell_translation_delegate.m",
    "shell_view_controller.h",
    "shell_view_controller.m",
  ]

  deps = [
    ":resources",
    "//ios/web_view:web_view+link",
  ]

  libs = [
    "CFNetwork.framework",
    "CoreFoundation.framework",
    "CoreGraphics.framework",
    "CoreText.framework",
    "Foundation.framework",
    "ImageIO.framework",
    "MobileCoreServices.framework",
    "Security.framework",
    "SystemConfiguration.framework",
    "UIKit.framework",
    "WebKit.framework",
    "resolv",
  ]

  configs += [ "//build/config/compiler:enable_arc" ]
}

bundle_data("resources") {
  visibility = [ ":shell" ]
  sources = [
    "Default-568h@2x.png",
    "textfield_background@2x.png",
    "toolbar_back@2x.png",
    "toolbar_forward@2x.png",
    "toolbar_more_horiz@2x.png",
    "toolbar_stop@2x.png",
  ]
  outputs = [
    "{{bundle_resources_dir}}/{{source_file_part}}",
  ]
}