# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

if (is_android) {
  import("//build/config/android/rules.gni")
}

source_set("feed_core") {
  sources = [
    "feed_content_database.cc",
    "feed_content_database.h",
    "feed_content_mutation.cc",
    "feed_content_mutation.h",
    "feed_content_operation.cc",
    "feed_content_operation.h",
    "feed_image_database.cc",
    "feed_image_database.h",
    "feed_image_manager.cc",
    "feed_image_manager.h",
    "feed_journal_database.cc",
    "feed_journal_database.h",
    "feed_journal_mutation.cc",
    "feed_journal_mutation.h",
    "feed_journal_operation.cc",
    "feed_journal_operation.h",
    "feed_networking_host.cc",
    "feed_networking_host.h",
    "feed_scheduler_host.cc",
    "feed_scheduler_host.h",
    "pref_names.cc",
    "pref_names.h",
    "refresh_throttler.cc",
    "refresh_throttler.h",
    "time_serialization.cc",
    "time_serialization.h",
    "user_classifier.cc",
    "user_classifier.h",
  ]

  public_deps = [
    "//base",
    "//components/feed:feature_list",
    "//components/feed/core/proto",
    "//components/image_fetcher/core:core",
    "//components/leveldb_proto",
    "//net",
  ]

  deps = [
    "//components/data_use_measurement/core",
    "//components/prefs",
    "//components/variations",
    "//components/variations/net",
    "//components/variations/service",
    "//components/web_resource",
    "//google_apis",
    "//services/identity/public/cpp",
    "//services/network/public/cpp",
    "//services/network/public/mojom",
    "//third_party/zlib/google:compression_utils",
  ]
}

if (is_android) {
  java_cpp_enum("feed_core_java_enums_srcjar") {
    sources = [
      "feed_scheduler_host.h",
    ]
  }
}

source_set("core_unit_tests") {
  testonly = true
  sources = [
    "feed_content_database_unittest.cc",
    "feed_content_mutation_unittest.cc",
    "feed_image_database_unittest.cc",
    "feed_image_manager_unittest.cc",
    "feed_journal_database_unittest.cc",
    "feed_journal_mutation_unittest.cc",
    "feed_networking_host_unittest.cc",
    "feed_scheduler_host_unittest.cc",
    "refresh_throttler_unittest.cc",
    "user_classifier_unittest.cc",
  ]

  deps = [
    ":feed_core",
    "//base",
    "//base/test:test_support",
    "//components/leveldb_proto:test_support",
    "//components/prefs:test_support",
    "//components/variations:test_support",
    "//components/web_resource",
    "//net:test_support",
    "//services/identity/public/cpp",
    "//services/identity/public/cpp:test_support",
    "//services/network:test_support",
    "//services/network/public/cpp",
    "//services/network/public/mojom",
    "//third_party/zlib/google:compression_utils",
    "//ui/gfx:test_support",
  ]
}