# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ios/web/js_compile.gni")

source_set("find_in_page") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "find_in_page_controller.h",
    "find_in_page_controller.mm",
    "find_in_page_model.h",
    "find_in_page_model.mm",
    "find_tab_helper.h",
    "find_tab_helper.mm",
    "js_findinpage_manager.h",
    "js_findinpage_manager.mm",
  ]
  deps = [
    ":injected_js",
    "//base",
    "//ios/chrome/browser/web",
    "//ios/web",
  ]
  libs = [ "CoreGraphics.framework" ]
}

# TODO(crbug.com/487804): use js_compile_checked instead once the errors have
# been fixed.
js_compile_unchecked("injected_js") {
  sources = [
    "resources/find_in_page.js",
  ]
}

source_set("unit_tests") {
  testonly = true
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "find_in_page_js_unittest.mm",
    "find_tab_helper_unittest.mm",
    "js_findinpage_manager_unittest.mm",
  ]
  deps = [
    ":find_in_page",
    "//base",
    "//base/test:test_support",
    "//ios/chrome/browser/web:test_support",
    "//ios/web",
    "//ios/web/public/test",
    "//ios/web/public/test/fakes",
    "//testing/gtest",
  ]
}