# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//build/config/compiler/compiler.gni")
import("//build/config/features.gni")
import("//mojo/public/tools/bindings/mojom.gni")
import("//testing/test.gni")

component("blink_common") {
  output_name = "blink_common"

  visibility = [
    "//chrome/*",
    "//content/*",
    "//third_party/WebKit/*",
    ":*",
  ]

  defines = [ "BLINK_COMMON_IMPLEMENTATION=1" ]

  sources = [
    "client_hints/client_hints.cc",
    "client_hints/client_hints.h",
    "common_export.h",
    "device_memory/approximated_device_memory.cc",
    "device_memory/approximated_device_memory.h",
    "message_port/message_port_channel.cc",
    "message_port/message_port_channel.h",
    "message_port/message_port_message.cc",
    "message_port/message_port_message.h",
    "message_port/message_port_message_struct_traits.cc",
    "message_port/message_port_message_struct_traits.h",
    "mime_util/mime_util.cc",
    "mime_util/mime_util.h",
    "origin_trials/trial_token.cc",
    "origin_trials/trial_token.h",
    "origin_trials/trial_token_validator.cc",
    "origin_trials/trial_token_validator.h",
  ]

  public_deps = [
    ":mojo_bindings",
  ]

  deps = [
    "//base",
    "//mojo/common:common_base",
    "//mojo/public/cpp/system",
    "//net",
  ]

  # iOS doesn't use and must not depend on //media
  if (!is_ios) {
    deps += [ "//media" ]
  }
}

test("blink_common_unittests") {
  visibility = [ "*" ]

  sources = [
    "device_memory/approximated_device_memory_unittest.cc",
    "mime_util/mime_util_unittest.cc",
    "origin_trials/trial_token_unittest.cc",
    "origin_trials/trial_token_validator_unittest.cc",
    "test/run_all_unittests.cc",
  ]

  deps = [
    ":blink_common",
    "//base",
    "//base/test:test_support",
    "//net",
    "//testing/gtest",
    "//third_party/boringssl",
  ]
}

mojom("mojo_bindings") {
  visibility = [ "//third_party/WebKit/*" ]

  sources = [
    "message_port/message_port.mojom",
  ]
}