# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//build/config/chromecast_build.gni")

declare_args() {
  # Set true to use accurate but more expensive method for GetMediaTime().
  cma_use_accurate_media_time = is_cast_audio_only
}

source_set("pipeline") {
  sources = [
    "audio_decoder_software_wrapper.cc",
    "audio_decoder_software_wrapper.h",
    "audio_pipeline_impl.cc",
    "audio_pipeline_impl.h",
    "av_pipeline_client.cc",
    "av_pipeline_client.h",
    "av_pipeline_impl.cc",
    "av_pipeline_impl.h",
    "decrypt_util.cc",
    "decrypt_util.h",
    "load_type.h",
    "media_pipeline_client.cc",
    "media_pipeline_client.h",
    "media_pipeline_impl.cc",
    "media_pipeline_impl.h",
    "media_pipeline_observer.cc",
    "media_pipeline_observer.h",
    "video_pipeline_client.cc",
    "video_pipeline_client.h",
    "video_pipeline_impl.cc",
    "video_pipeline_impl.h",
  ]

  public_deps = [
    "//chromecast/public",
    "//chromecast/public/media",
  ]

  deps = [
    ":cma_pipeline_features",
    "//base",
    "//chromecast/base/metrics:metrics",
    "//chromecast/media/base",
    "//chromecast/media/cdm",
    "//chromecast/media/cma/backend",
    "//chromecast/media/cma/base",
    "//chromecast/media/cma/decoder",
    "//crypto",
    "//crypto:platform",
    "//media",
    "//third_party/boringssl",
  ]
}

buildflag_header("cma_pipeline_features") {
  header = "cma_pipeline_features.h"

  flags = [ "CMA_USE_ACCURATE_MEDIA_TIME=$cma_use_accurate_media_time" ]
}