naiveproxy/chrome/chrome_cleaner/constants/BUILD.gn

# Copyright (c) 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chrome_build.gni")
import("//build/util/lastchange.gni")
import("//build/util/process_version.gni")

declare_args() {
  reporter_branding_path = "REPORTER_BRANDING"
  cleaner_branding_path = "CLEANER_BRANDING"
  version_path = "VERSION"
  lastchange_path = lastchange_file
}

process_version("version_header") {
  sources = [
    cleaner_branding_path,
    lastchange_path,
    version_path,
  ]

  template_file = "version.h.in"
  output = "$target_gen_dir/version.h"
}

process_version("chrome_cleanup_tool_branding_header") {
  sources = [
    cleaner_branding_path,
  ]

  template_file = "branding.h.in"

  output = "$target_gen_dir/chrome_cleanup_tool_branding.h"
}

process_version("software_reporter_tool_branding_header") {
  sources = [
    reporter_branding_path,
  ]

  template_file = "branding.h.in"

  output = "$target_gen_dir/software_reporter_tool_branding.h"
}

source_set("common_strings") {
  sources = [
    "chrome_cleaner_switches.cc",
    "chrome_cleaner_switches.h",
    "common_registry_names.cc",
    "common_registry_names.h",
  ]
}

source_set("uws_id") {
  sources = [
    "uws_id.h",
  ]
}